style_system | Converting LJ's Gradient Strip Layout

Hi, I'm probably asking for the impossible here.

I've always liked Livejournal's Gradient Strip layout - if anybody still remembers it ;) I've had it as my LJ layout for years and luckily never changed it as they've since done away with it, like a lot of other orginal LJ layouts *eye roll*

So I have the raw source code here

# -*-s2-*-
layerinfo type = "layout";
layerinfo name = "Gradient Strip";
layerinfo lang = "en";

layerinfo author_name = "Dana Ankenbauer";
layerinfo author_email = "alsatia@livejournal.com";
layerinfo des = "Text-based navigation accented by rainbow or monochrome textured gradients.";
layerinfo redist_uniq = "gradient/layout";
layerinfo previews = "gradient/layout.jpg";

################################################################################
#
# Properties
#

propgroup presentation {
  property int entry_width {
      des = "Width of entries as a percentage of the page width.";
      values = "55|55%|65|65%|75|75%|85|85%";
   }
   property use page_recent_items;
   property use view_comment_subject;
   property use page_friends_items;
   property bool show_entry_userpic {
      des = "Show userpic with entries on Recent Entries page";
   }
   property use use_shared_pic;
   property use view_entry_disabled;
   property use page_day_sortorder;
   property use page_year_sortorder;
   property bool lj_user_tags {
      des = "Use lj user tags for links to entry and comment authors.";
   }
   property bool security_icons {
      des = "Show security icons on entries.";
   }
   property bool mood_icons {
      des = "Show mood icons on entries.";
   }
   property bool subject_icons {
      des = "Show subject icons on comments.";
   }
   property use external_stylesheet;
   property use tags_aware;
   property string body_cursor {
      des = "Cursor on Page Body";
      values = "default|Default|auto|Auto|crosshair|Crosshair|help|Help|move|Move|pointer|Pointer|text|Text|wait|Wait|n-resize|North Resize|ne-resize|Northeast Resize|e-resize|East Resize|se-resize|Southeast Resize|s-resize|South Resize|sw-resize|Southwest Resize|w-resize|West Resize|nw-resize|Northwest Resize";
   }
   property string link_cursor {
      des = "Cursor on Link Hover";
      values = "default|Default|auto|Auto|crosshair|Crosshair|help|Help|move|Move|pointer|Pointer|text|Text|wait|Wait|n-resize|North Resize|ne-resize|Northeast Resize|e-resize|East Resize|se-resize|Southeast Resize|s-resize|South Resize|sw-resize|Southwest Resize|w-resize|West Resize|nw-resize|Northwest Resize";
   }
   property string underline_links {
      des = "Underline Links";
      values = "always|Always|hover|When Hovered|never|Never";
   }
   property string border_style {
      des = "Style of Borders";
      values = "dotted|Dotted|double|Double|dashed|Dashed|groove|Groove|inset|Inset|ridge|Ridge|solid|Solid|outset|Outset";
   }
   property string border_width {
      des = "Width of Borders";
      note = "Values should be in positive whole numbers, followed by 'px'.  If blank, ideal width for your border style will be used automatically.";
      example = "3px";
   }
   property string entry_line_height {
      des = "Line Height in Entries";
      note = "Height of lines as a percentage of font size.";
      values = "80%|80%|100%|100%|120%|120%|140%|140%|160%|160%|180%|180%|200%|200%";
   }
   property string text_align {
      des = "Text Alignment";
      note = "Adjusts alignment of entry and comment text.";
      values = "left|Left|center|Center|right|Right|justify|Justify";
   }
   property string text_transform {
      des = "Text Transformation";
      note = "Adjusts capitalization in all page text.";
      values = "none|(none)|capitalize|Capitalize|uppercase|UPPERCASE|lowercase|lowercase";
   }
   property use linklist_support;
   property use custom_control_strip_colors;

set entry_width = 65;
   set show_entry_userpic = true;
   set use_shared_pic = false;
   set view_entry_disabled = false;
   set page_day_sortorder = "forward";
   set page_year_sortorder = "forward";
   set lj_user_tags = true;
   set security_icons = true;
   set mood_icons = true;
   set subject_icons = true;
   set external_stylesheet = true;
   set tags_aware = true;
   set underline_links = "never";
   set body_cursor = "default";
   set link_cursor = "pointer";
   set border_style = "solid";
   set border_width = "";
   set entry_line_height = "120%";
   set text_transform = "none";
   set text_align = "left";
}

propgroup colors {
   property Color page_bgcolor {
      des = "Page Background";
   }
   property Color head_bgcolor {
      des = "Header Background";
   }
   property Color head_border_color {
      des = "Header Border";
      note = "If blank, color will match Header Background.";
   }
   property Color head_fgcolor {
      des = "Header Text";
   }
   property bool head_transparency {
      des = "Header Transparency";
      note = "Overrides options for Header Background and Border.";
   }
   property Color edge_bgcolor {
      des = "Content Edge Background";
   }
   property Color edge_border_color {
      des = "Content Border Color";
      note = "If blank, color will match Content Edge Background.";
   }
   property bool edge_transparency {
      des = "Content Edge Transparency";
      note = "Overrides options for Content Edge Background and Border";
   }
   property Color entry_bgcolor {
      des = "Content Box Background";
   }
   property Color entry_fgcolor {
      des = "Content Text";
   }
   property Color link_color {
      des = "Unvisited Links";
   }
   property Color vlink_color {
      des = "Visited Links";
      note = "If blank, color will match unvisited links.";
   }
   property Color hlink_color {
      des = "Hovered Links";
      note = "If blank, color will be a darker shade of unvisited links";
   }
   property Color alink_color {
      des = "Active Links";
      note = "If blank, color will match hovered links.";
   }
   property Color withdays_bgcolor {
      des = "Calendar Day Background (With Entries)";
      note = "If blank, color will match content background.";
   }
   property Color withoutdays_bgcolor {
      des = "Calendar Day Background (Without Entries)";
      note = "If blank, color will match content background or be a darker shade of entries with days (if defined).";
   }
   property Color month_subjects_bgcolor {
      des = "Background Color for Month Subject Lists";
      note = "If blank, color will match content background or calendar days with entries (if defined).";
   }
   property use control_strip_bgcolor;
   property use control_strip_fgcolor;
   property use control_strip_bordercolor;
   property use control_strip_linkcolor;

set page_bgcolor = "#ffffff";
  set head_bgcolor = "#000000";
  set head_border_color = "";
  set head_fgcolor = "#ffffff";
  set head_transparency = false;
  set edge_bgcolor = "#000000";
  set edge_border_color = "";
  set edge_transparency = false;
  set entry_bgcolor = "#ffffff";
  set entry_fgcolor = "#000000";
  set link_color = "#ff0000";
  set vlink_color = "";
  set hlink_color = "";
  set alink_color = "";
  set withdays_bgcolor = "";
  set withoutdays_bgcolor = "";
  set month_subjects_bgcolor = "";
}

propgroup fonts {
   property string base_font {
      des = "Base Font";
   }
   property string base_font_fallback {
      des = "Base Font Family";
      note = "If preferred base font is unavailable, this font type will be used.";
      values = "cursive|cursive|fantasy|fantasy|monospace|monospace|sans-serif|sans-serif|serif|serif";
   }
   property string base_font_size {
      des = "Base Font Size";
      values = "small|Small|medium|Medium|large|Large";
   }
   property string meta_font_size {
      des = "Size of Font in Entry and Comment Metadata";
      note = "Size is relative to the base font.";
      values = "smaller|Smaller|same|Same|larger|Larger";
   }
   property string title_font {
      des = "Title Font";
      note = "If blank, base font will be used for page title.";
   }
   property string title_font_fallback {
      des = "Title Font Family";
      note = "If preferred title font is unavailable, this font type will be used.";
      values = "cursive|cursive|fantasy|fantasy|monospace|monospace|sans-serif|sans-serif|serif|serif";
   }
   property string title_font_size {
      des = "Title Font Size";
      values = "small|Small|medium|Medium|large|Large";
   }

set base_font = "Arial";
   set base_font_fallback = "sans-serif";
   set base_font_size = "medium";
   set meta_font_size = "smaller";
   set title_font = "Arial";
   set title_font_fallback = "sans-serif";
   set title_font_size = "medium";
}

propgroup images {
   property string background_texture {
      des = "Texture for Page Background";
      values = "none|None|brushed_metal|Brushed Metal|burlap|Burlap|camouflage|Camouflage|canvas|Canvas|chalk|Chalk|cork|Cork|explosion|Explosion|fibers|Fibers|floral|Floral|ice|Ice|manila|Manila|marble|Marble|paper|Paper|ridge|Ridge|rough|Rough|stucco|Stucco|terracotta|Terracotta|type|Type|wavy|Wavy|weave|Weave|wood|Wood";
   }
   property string background_shade {
      des = "Lightness of Secondary Color for Page Background Textures";
      values = "lightest|Lightest|lighter|Lighter|medium|Medium|darker|Darker|darkest|Darkest";
   }
   property string background_image {
      des = "Background image URL";
      note = "Setting this option overrides the texture options selected above.";
      example = "http://www.example.com/yourimage.jpg";
   }
   property string background_repeat {
      des = "Background Tiling";
      values = "no-repeat|Not Tiled|repeat-x|Tiled Horizontally|repeat-y|Tiled Vertically|repeat|Tiled Both Directions";
   }
   property string background_attachment {
      des = "Background Scrolling";
      values = "scroll|Scrolling|fixed|Fixed";
   }
   property string background_position_x {
      des = "Horizontal Position of Background";
      values = "left|Left|center|Center|right|Right";
   }
   property string background_position_y {
      des = "Vertical Position of Background";
      values = "top|Top|center|Center|bottom|Bottom";
   }

set background_texture = "none";
   set background_shade = "medium";
   set background_image = "";
   set background_repeat = "repeat";
   set background_attachment = "fixed";
   set background_position_x = "left";
   set background_position_y = "top";
}

propgroup text {
   property use text_tags;
   property use text_meta_mood;
   property use text_meta_music;
   property use text_meta_location;
   property use text_meta_groups;
   property use text_post_comment;
   property use text_post_comment_friends;
   property use text_read_comments;
   property use text_read_comments_friends;
   property string text_editlink {
      des = "Edit Link Text";
   }
   property string text_edittagslink {
      des = "Edit Tags Link Text";
   }
   property string text_memlink {
      des = "Add to Memories Link Text";
   }
   property use text_share;
   property use text_flag;
   property string text_tracklink {
      des = "Track New Comments Link Text";
   }
   property string text_untracklink {
      des = "Stop Tracking New Comments Link Text";
   }
   property string comment_link_divider {
      des = "Divider Between Edit, Add to Memories, and Comment Links";
      values = "~|~|::|::|—|—|x|x|#|#|>|>";
   }
   property string link_divider {
      des = "Divider Between Other Links";
      values = "~|~|::|::|—|—|x|x|#|#|>|>";
   }
   property string dateformat {
      des = "Date Format for Entries and Comments";
      values = "short|1/22/05|%%mm%%-%%dd%%-%%yyyy%%|01-22-2005|%%yy%%/%%m%%/%%d%%|05/1/22|%%yyyy%%-%%mm%%-%%dd%%|2005-01-22|%%d%%/%%m%%/%%yy%%|22/1/05|%%dd%%-%%mm%%-%%yyyy%%|22-01-2005|med|Jan. 22nd, 2005|%%mon%% %%d%%, %%yyyy%%|Jan. 22, 2005|long|January 22nd, 2005|%%month%% %%d%%, %%yyyy%%|January 22, 2005|med_day|Sat, Jan. 22nd, 2005|%%da%%, %%mon%% %%d%%, %%yyyy%%|Sat, Jan. 22, 2005|long_day|Saturday, January 22nd, 2005|%%day%%, %%month%% %%d%%, %%yyyy%%|Saturday, January 22, 2005";
   }
   property string timeformat {
      des = "Time Format for Entries and Comments";
      values = "short|01:22 pm|%%hh%%:%%min%% %%A%%M|01:22 PM|%%h%%:%%min%% %%a%%m|1:22 pm|%%h%%:%%min%% %%A%%M|1:22 PM|%%HH%%:%%min%%|13:22";
   }
   property string datedivider {
      des = "Divider Between Entry Date and Time";
      values = " |[blank space]| @ |@| at |at| — |—";
   }
   property string text_prevlink {
      des = "Text or Symbol for Link to Previous Page";
      values = "Previous|Previous|Earlier|Earlier|<|<|«|«|<-|<-|<=|<=|«-|«-";
   }
   property string text_nextlink {
      des = "Text or Symbol for Link to Next Page";
      values = "Next|Next|Later|Later|>|>|»|»|->|->|=>|=>|=»|-»";
   }
   property string text_tags_description {
      des = "Header for Tags Page";
      noui = 1;
   }

set text_tags = "Topics";
   set text_tag_uses = "1 entry // # entries";
   set text_meta_mood = "Mood";
   set text_meta_music = "Music";
   set text_meta_location = "Location";
   set text_meta_groups = "Groups";
   set text_post_comment = "Reply";
   set text_post_comment_friends = "Reply";
   set text_read_comments = "1 reply // # replies";
   set text_read_comments_friends = "1 reply // # replies";
   set text_editlink = "Edit Entry";
   set text_edittagslink = "Edit Topics";
   set text_memlink = "+Memory";
   set text_tracklink = "Track Replies";
   set text_untracklink = "Stop Tracking Replies";
   set comment_link_divider = "::";
   set link_divider = "::";
   set dateformat = "%%yyyy%%-%%mm%%-%%dd%%";
   set timeformat = "%%HH%%:%%min%%";
   set datedivider = " @ ";
   set text_prevlink = "Previous";
   set text_nextlink = "Next";
   set text_noentries_day = "No entries were posted on this date.";
   set text_nosubject = "Untitled";
   set text_month_screened_comments = "(plus screened)";
   set text_poster_anonymous = "Anonymous";
   set text_reply_nocomments = "Comments are not permitted on this entry.";
   set text_multiform_des = "Alter selected comments:";
   set text_multiform_btn = "Submit";
   set text_tags_description = "Topics List";
   property use text_showspam;
   property use text_hidespam;
   property use text_spam_comment;
   property use text_read_spam_comments;
   property use text_read_all_spam_comments;
}

propgroup header = "Header";
propgroup header {

property string head_size {
      des = "Header Size";
      note = "This size affects the header area and gradient blocks.";
      values = "small|Small|medium|Medium|large|Large";
   }
   property bool show_title {
      des = "Show Title and Subtitle in Header";
   }
   property Color gradient_base {
      des = "Base Color for Gradient Blocks";
      note = "All six colors will be automatically determined based on this color and your choice of gradient type.  Due to the process used to create the colors, the exact color you choose here may not be among the final six.";
   }
   property Color gradient_1 {
      des = "First color in gradient";
      noui = 1;
   }
   property Color gradient_2 {
      des = "Second color in gradient";
     noui = 1;
   }
   property Color gradient_3 {
      des = "Third color in gradient";
      noui = 1;
   }
   property Color gradient_4 {
      des = "Fourth color in gradient";
      noui = 1;
   }
   property Color gradient_5 {
      des = "Fifth color in gradient";
      noui = 1;
   }
   property Color gradient_6 {
      des = "Sixth color in gradient";
      noui = 1;
   }
   property string gradient_type {
      des = "Color Set for Gradient Blocks";
      note = "Monochrome is not recommended for light base colors.  Reverse Monochrome is not recommended for dark base colors.";
      values = "monochrome|Monochrome|spectrum|Spectrum|reverse_monochrome|Reverse Monochrome|reverse_spectrum|Reverse Spectrum";
   }
   property string gradient_texture {
      des = "Background Texture for Gradient Blocks";
      values = "none|None|brushed_metal|Brushed Metal|burlap|Burlap|camouflage|Camouflage|canvas|Canvas|chalk|Chalk|cork|Cork|explosion|Explosion|fibers|Fibers|floral|Floral|ice|Ice|manila|Manila|marble|Marble|paper|Paper|ridge|Ridge|rough|Rough|stucco|Stucco|terracotta|Terracotta|type|Type|wavy|Wavy|weave|Weave|wood|Wood";
   }
   property string gradient_shade {
      des = "Lightness of Secondary Color for Gradient Textures";
      values = "lightest|Lightest|lighter|Lighter|medium|Medium|darker|Darker|darkest|Darkest";
   }
   property string blockbg_1 {
      des = "Background image for first gradient block";
      noui = 1;
   }
   property string blockbg_2 {
      des = "Background image for second gradient block";
      noui = 1;
   }
   property string blockbg_3 {
      des = "Background image for third gradient block";
      noui = 1;
   }
   property string blockbg_4 {
      des = "Background image for fourth gradient block";
      noui = 1;
   }
   property string blockbg_5 {
      des = "Background image for fifth gradient block";
      noui = 1;
   }
   property string blockbg_6 {
      des = "Background image for sixth gradient block";
      noui = 1;
   }
   property string fifth_block_link {
      des = "Link for 5th gradient block";
      note = "If you select 'Website' but do not have a website link in your userinfo, this will default to the Tags List link.";
      values = "memories|Memories|scrapbook|ScrapBook|tags|Tags List|todo|To-Do List|update|Update Journal|userpics|User Pictures|website|Website";
   }
   property string sixth_block_link {
      des = "Link for 6th gradient block";
      note = "If you select 'Website' but do not have a website link in your userinfo, this will default to the To-Do List link.";
      values = "memories|Memories|scrapbook|ScrapBook|tags|Tags List|todo|To-Do List|update|Update Journal|userpics|User Pictures|website|Website";
   }

set head_size = "medium";
   set show_title = true;
   set gradient_base = "#ff0000";
   set gradient_type = "spectrum";
   set gradient_texture = "none";
   set gradient_shade = "medium";
   set fifth_block_link = "tags";
   set sixth_block_link = "website";
}

propgroup customcss {
   property use include_default_stylesheet;
   property use linked_stylesheet;
   property use custom_css;
}

################################################################################
#
# Color Scheme Functions
#

function color_spectrum(Color base) : Color[] {
   var int saturation = $base->saturation();
   var int lightness = $base->lightness();
   var Color color_one = $base->clone();
   var Color color_two = $base->clone();
   var Color color_three = $base->clone();

var Color color_four = $base->clone();
   var Color color_five = $base->clone();
   var Color color_six = $base->clone();

$color_one->hue(250);
   $color_one->saturation($saturation);
   $color_one->lightness($lightness);

$color_two->hue(25);
   $color_two->saturation($saturation);
   $color_two->lightness($lightness);

$color_three->hue(40);
   $color_three->saturation($saturation);
   $color_three->lightness($lightness);

$color_four->hue(70);
   $color_four->saturation($saturation);
   $color_four->lightness($lightness);

$color_five->hue(150);
   $color_five->saturation($saturation);
   $color_five->lightness($lightness);

$color_six->hue(200);
   $color_six->saturation($saturation);
   $color_six->lightness($lightness);

return [$base, $color_one, $color_two, $color_three, $color_four, $color_five, $color_six];
}

################################################################################
#
# Date Functions
#

function lay_historylink(Entry e) {
   var string eyear2 = $e.time->date_format("%%yy%%");
   var string eyear4 = $e.time->date_format("%%yyyy%%");
   var string emonth1 = $e.time->date_format("%%m%%");
   var string emonth2 = $e.time->date_format("%%mm%%");
   var string emonth_short = $e.time->date_format("%%mon%%");
   var string emonth_long = $e.time->date_format("%%month%%");
   var string eday1 = $e.time->date_format("%%d%%");
   var string eday2 = $e.time->date_format("%%dd%%");
   var string ewday_short = $e.time->date_format("%%da%%");
   var string ewday_long = $e.time->date_format("%%day%%");
   var string eday_ord = $e.time->date_format("%%dayord%%");
   var string ejbase = $e.journal->base_url();

if ($*dateformat == "short") {
      """<a href="$ejbase/$eyear4/$emonth2/">$emonth1</a>/<a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday2</a>/<a href="$ejbase/$eyear4/">$eyear2</a>""";
   }
   elseif ($*dateformat == "%%mm%%-%%dd%%-%%yyyy%%") {
      """<a href="$ejbase/$eyear4/$emonth2/">$emonth2</a>-<a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday2</a>-<a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   elseif ($*dateformat == "%%yy%%/%%m%%/%%d%%") {
      """<a href="$ejbase/$eyear4/">$eyear2</a>/<a href="$ejbase/$eyear4/$emonth2/">$emonth1</a>/<a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday1</a>""";
   }
   elseif ($*dateformat == "%%yyyy%%-%%mm%%-%%dd%%") {
      """<a href="$ejbase/$eyear4/">$eyear4</a>-<a href="$ejbase/$eyear4/$emonth2/">$emonth2</a>-<a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday2</a>""";
   }
   elseif ($*dateformat == "%%d%%/%%m%%/%%yy%%") {

"""<a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday1</a>/<a href="$ejbase/$eyear4/$emonth2/">$emonth1</a>/<a href="$ejbase/$eyear4/">$eyear2</a>""";
   }
   elseif ($*dateformat == "%%dd%%-%%mm%%-%%yyyy%%") {
      """<a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday2</a>-<a href="$ejbase/$eyear4/$emonth2/">$emonth2</a>-<a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   elseif ($*dateformat == "med") {
      """<a href="$ejbase/$eyear4/$emonth2/">$emonth_short</a> <a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday_ord</a>, <a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   elseif ($*dateformat == "%%mon%% %%d%%, %%yyyy%%") {
      """<a href="$ejbase/$eyear4/$emonth2/">$emonth_short</a> <a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday1</a>, <a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   elseif ($*dateformat == "long") {
      """<a href="$ejbase/$eyear4/$emonth2/">$emonth_long</a> <a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday_ord</a>, <a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   elseif ($*dateformat == "%%month%% %%d%%, %%yyyy%%") {
      """<a href="$ejbase/$eyear4/$emonth2/">$emonth_long</a> <a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday1</a>, <a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   elseif ($*dateformat == "med_day") {
      """$ewday_short, <a href="$ejbase/$eyear4/$emonth2/">$emonth_short</a> <a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday_ord</a>, <a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   elseif ($*dateformat == "%%da%%, %%mon%% %%d%%, %%yyyy%%") {
      """$ewday_short, <a href="$ejbase/$eyear4/$emonth2/">$emonth_short</a> <a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday1</a>, <a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   elseif ($*dateformat == "long_day") {
      """$ewday_long, <a href="$ejbase/$eyear4/$emonth2/">$emonth_long</a> <a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday_ord</a>, <a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   elseif ($*dateformat == "%%day%%, %%month%% %%d%%, %%yyyy%%") {
      """$ewday_long, <a href="$ejbase/$eyear4/$emonth2/">$emonth_long</a> <a href="$ejbase/$eyear4/$emonth2/$eday2/">$eday1</a>, <a href="$ejbase/$eyear4/">$eyear4</a>""";
   }
   else {
      print $e.time->date_format("$*dateformat");
   }
}

################################################################################
#
# Property Initialization
#

function prop_init() {
   if ($*title_font == "") {
      $*title_font = $*base_font;
   }
   if ($*title_font_fallback == "") {
      $*title_font_fallback = $*base_font_fallback;
   }

if (isnull $*head_border_color) {
      $*head_border_color = $*head_bgcolor;
   }
   if (isnull $*edge_border_color) {
      $*edge_border_color = $*edge_bgcolor;
   }
   if ($*border_width == "") {
      if (($*border_style == "solid")

or ($*border_style == "dashed")
         or ($*border_style == "dotted")) {
            $*border_width = "1px";
      }
      elseif (($*border_style == "groove")
             or ($*border_style == "ridge")
             or ($*border_style == "inset")
             or ($*border_style == "outset")) {
                $*border_width = "2px";
      }
      elseif ($*border_style == "double") {
         $*border_width = "3px";
      }
   }

if (isnull $*vlink_color) {
      $*vlink_color = $*link_color;
   }
   if (isnull $*hlink_color) {
      $*hlink_color = $*link_color->darker(20);
   }
   if (isnull $*alink_color) {
      $*alink_color = $*hlink_color;
   }

if (isnull $*withdays_bgcolor) {
      $*withdays_bgcolor = $*entry_bgcolor;
   }
   if (isnull $*withoutdays_bgcolor) {
      $*withoutdays_bgcolor = $*withdays_bgcolor->darker(10);
   }
   if (isnull $*month_subjects_bgcolor) {
      if (defined $*withdays_bgcolor) {
         $*month_subjects_bgcolor = $*withdays_bgcolor;
      }
      else {
         $*month_subjects_bgcolor = $*entry_bgcolor;
      }
   }

if ($*gradient_type == "monochrome") {
      $*gradient_1 = $*gradient_base;
      if (isnull $*gradient_2)  { $*gradient_2 = $*gradient_base->lighter(15); }
      if (isnull $*gradient_3)  { $*gradient_3 = $*gradient_base->lighter(30); }
      if (isnull $*gradient_4)  { $*gradient_4 = $*gradient_base->lighter(45); }
      if (isnull $*gradient_5)  { $*gradient_5 = $*gradient_base->lighter(60); }
      if (isnull $*gradient_6)  { $*gradient_6 = $*gradient_base->lighter(75); }
   }
   elseif ($*gradient_type == "reverse_monochrome") {
      $*gradient_1 = $*gradient_base;
      if (isnull $*gradient_2)  { $*gradient_2 = $*gradient_base->darker(15); }
      if (isnull $*gradient_3)  { $*gradient_3 = $*gradient_base->darker(30); }
      if (isnull $*gradient_4)  { $*gradient_4 = $*gradient_base->darker(45); }
      if (isnull $*gradient_5)  { $*gradient_5 = $*gradient_base->darker(60); }
      if (isnull $*gradient_6)  { $*gradient_6 = $*gradient_base->darker(75); }
   }
   elseif ($*gradient_type == "reverse_spectrum") {
      var Color[] spectrum = color_spectrum($*gradient_base);
      if (isnull $*gradient_1) { $*gradient_1 = $spectrum[6]; }
      if (isnull $*gradient_2) { $*gradient_2 = $spectrum[5]; }
      if (isnull $*gradient_3) { $*gradient_3 = $spectrum[4]; }
      if (isnull $*gradient_4) { $*gradient_4 = $spectrum[3]; }
      if (isnull $*gradient_5) { $*gradient_5 = $spectrum[2]; }
      if (isnull $*gradient_6) { $*gradient_6 = $spectrum[1]; }

}
   else {
      var Color[] spectrum = color_spectrum($*gradient_base);
      if (isnull $*gradient_1) { $*gradient_1 = $spectrum[1]; }
      if (isnull $*gradient_2) { $*gradient_2 = $spectrum[2]; }
      if (isnull $*gradient_3) { $*gradient_3 = $spectrum[3]; }
      if (isnull $*gradient_4) { $*gradient_4 = $spectrum[4]; }
      if (isnull $*gradient_5) { $*gradient_5 = $spectrum[5]; }
      if (isnull $*gradient_6) { $*gradient_6 = $spectrum[6]; }
   }

var Color gradient_shade;
   if ($*gradient_shade == "lightest") { $gradient_shade = "#ffffff"; }
   if ($*gradient_shade == "lighter") { $gradient_shade = "#cccccc"; }
   if ($*gradient_shade == "medium") { $gradient_shade = "#aaaaaa"; }
   if ($*gradient_shade == "darker") { $gradient_shade = "#333333"; }
   if ($*gradient_shade == "darkest") { $gradient_shade = "#000000"; }

if ($*gradient_texture != "none") {
      if ($*blockbg_1 == "") { $*blockbg_1 = palimg_tint("textures/$*gradient_texture" + ".png", $*gradient_1, $gradient_shade); }
      if ($*blockbg_2 == "") { $*blockbg_2 = palimg_tint("textures/$*gradient_texture" + ".png", $*gradient_2, $gradient_shade); }
      if ($*blockbg_3 == "") { $*blockbg_3 = palimg_tint("textures/$*gradient_texture" + ".png", $*gradient_3, $gradient_shade); }
      if ($*blockbg_4 == "") { $*blockbg_4 = palimg_tint("textures/$*gradient_texture" + ".png", $*gradient_4, $gradient_shade); }
      if ($*blockbg_5 == "") { $*blockbg_5 = palimg_tint("textures/$*gradient_texture" + ".png", $*gradient_5, $gradient_shade); }
      if ($*blockbg_6 == "") { $*blockbg_6 = palimg_tint("textures/$*gradient_texture" + ".png", $*gradient_6, $gradient_shade); }
   }

var Color background_shade;
   if ($*background_shade == "lightest") { $background_shade = "#ffffff"; }
   if ($*background_shade == "lighter") { $background_shade = "#cccccc"; }
   if ($*background_shade == "medium") { $background_shade = "#aaaaaa"; }
   if ($*background_shade == "darker") { $background_shade = "#333333"; }
   if ($*background_shade == "darkest") { $background_shade = "#000000"; }

if (($*background_image == "")
      and ($*background_texture != "none")) { $*background_image = palimg_tint("textures/$*background_texture" + ".png", $*page_bgcolor, $background_shade); }

if ($*head_transparency == true) {
      $*head_bgcolor = "transparent";
   }
   if ($*edge_transparency == true) {
      $*edge_bgcolor = "transparent";
   }

if ($*control_strip_bgcolor.as_string == "") {
      $*control_strip_bgcolor = $*entry_bgcolor;
   }
   if ($*control_strip_fgcolor.as_string == "") {
      $*control_strip_fgcolor = $*entry_fgcolor;
   }
   if ($*control_strip_bordercolor.as_string == "") {
      $*control_strip_bordercolor = $*edge_border_color;
   }
   if ($*control_strip_linkcolor.as_string == "") {
      $*control_strip_linkcolor = $*link_color;
   }

$*theme_bgcolor = $*entry_bgcolor;
    $*theme_fgcolor = $*entry_fgcolor;
    $*theme_bordercolor = $*edge_border_color;
    $*theme_linkcolor = $*link_color;
}

################################################################################
#
# Stylesheet
#

function appended_to_stylesheet() {
}

function print_stylesheet() {
   var string title_size;
   var string head_height;
   var string block_size;

if ($*head_size == "small") {
      $head_height = "40px";
      $block_size = "50px";
   }
   elseif ($*head_size == "medium") {
      $head_height = "65px";
      $block_size = "75px";
   }
   else {
      $head_height = "90px";
      $block_size = "100px";
   }

var string entry_width;
   var string margin_left;
   var string margin_right;

if ($*entry_width == 55) {
      $entry_width = "55%";
      $margin_left = "25%";
      $margin_right = "15%";
   }
   elseif ($*entry_width == 65) {
      $entry_width = "65%";
      $margin_left = "20%";
      $margin_right = "10%";
   }
   elseif ($*entry_width == 75) {
      $entry_width = "75%";
      $margin_left = "15%";
      $margin_right = "5%";
   }
   elseif ($*entry_width == 85) {
      $entry_width = "85%";
      $margin_left = "7%";
      $margin_right = "3%";
   }

var int top_margin = 15;

"""
   /* Basic HTML */
   a {
      color: $*link_color;
      """; if ($*underline_links == "always") { """text-decoration: underline; """; } """
      cursor: $*link_cursor;
   }
   a:visited {
      color: $*vlink_color;
      """; if ($*underline_links == "always") { """text-decoration: underline; """; } """
      cursor: $*link_cursor;
   }
    a:hover {
      color: $*hlink_color;
      """; if ($*underline_links != "never") { """text-decoration: underline; """; } """
      cursor: $*link_cursor;
   }
   a:active {
      color: $*alink_color;
      """; if ($*underline_links == "always") { """text-decoration: underline; """; } """
      cursor: $*link_cursor;
   }
   blockquote {
      margin-left: 10px;
      padding: 5px;
      border-left: 1px $*border_style $*edge_border_color;
      border-right: 1px $*border_style $*edge_border_color;
   }
   hr {
      height: 1px;
      color: $*edge_border_color;
      background: $*edge_border_color;
      border: 0;
      width: 75%;
   }
   img {
      border: 0;
   }
   img.border {
      border: 1px $*border_style $*edge_border_color;
   }
   ol {
      list-style-type: decimal;
   }
   ul {
      list-style-type: square;
   }
   ul ul {
      list-style-type: circle;
   }
   ul ul ul {
      list-style-type: disc;
   }
   q {
      font-style: italic;
   }

/* Body and header */

body {
      margin: 0;
      background: $*page_bgcolor;""";
   if (clean_url($*background_image) != "") {
      """
      background-image: url($*background_image);
      background-repeat: $*background_repeat;
      background-attachment: $*background_attachment;
      background-position: $*background_position_x $*background_position_y;""";
   }
      """
      color: $*entry_fgcolor;
      font-family: "$*base_font", $*base_font_fallback;
      font-size: $*base_font_size;
      cursor: $*body_cursor;
      text-transform: $*text_transform;

}
   .wrapper {
      position: relative;
      }
   #header {
      margin: 0 0 30px 0;
      padding: 10px 10px 10px 0;
      height: $head_height;
      max-height: $head_height;
      background: $*head_bgcolor;
      color: $*head_fgcolor;
      font-family: "$*title_font", $*title_font_fallback;
      font-size: $*title_font_size;""";
      if ($*head_transparency == false) {
         """border-bottom: $*border_width $*border_style $*head_border_color;""";
      }
   """}
   #title {
      max-width: 33%;
      height: $head_height;
      max-height: $head_height;
      padding: 0;
      float: right;
      overflow: hidden;
   }
   #subtitle {
      font-size: 80%;
   }
   #gradient {
      position: absolute;
      top: ${top_margin}px;
      left: 10px;
   }
   td.gradient {
      height: $block_size;
      width: $block_size;
      border: $*border_width $*border_style $*head_border_color;
   }

td.gradient img {
      border: 0;
   }
   #td1 {
      background: $*gradient_1"""; if ($*blockbg_1 != "") { """ url($*blockbg_1) center center"""; }""";
   }
   #td2 {
      background: $*gradient_2"""; if ($*blockbg_2 != "") { """ url($*blockbg_2) center center"""; }""";
   }
   #td3 {
      background: $*gradient_3"""; if ($*blockbg_3 != "") { """ url($*blockbg_3) center center"""; }""";
   }
   #td4 {
      background: $*gradient_4"""; if ($*blockbg_4 != "") { """ url($*blockbg_4) center center"""; }""";
   }
   #td5 {
      background: $*gradient_5"""; if ($*blockbg_5 != "") { """ url($*blockbg_5) center center"""; }""";
   }
   #td6 {
      background: $*gradient_6"""; if ($*blockbg_6 != "") { """ url($*blockbg_6) center center"""; }""";
   }

/* Content boxes */

div.contentholder {
      width: $entry_width;
      min-height: 175px;
      margin: 0 $margin_right 10px $margin_left;
      background: $*edge_bgcolor;""";
      if ($*edge_transparency == false) {
         """border: $*border_width $*border_style $*edge_border_color;""";
      }
   """}
   * html div.contentholder {
      height: 175px;
   }
   table.contentgradient {
      margin: 5px;
      float: right;
      overflow: hidden;
   }
   * html table.contentgradient {
      margin: 2px;
      padding: 0;
   }
   table.contentgradient td {
      height: 25px;
      width: 25px;
      border: $*border_width $*border_style $*edge_border_color;
   }
   td.td1 {
      background: $*gradient_1"""; if ($*blockbg_1 != "") { """ url($*blockbg_1) center center"""; }""";
   }
   td.td2 {
      background: $*gradient_2"""; if ($*blockbg_2 != "") { """ url($*blockbg_2) center center"""; }""";
   }
   td.td3 {
      background: $*gradient_3"""; if ($*blockbg_3 != "") { """ url($*blockbg_3) center center"""; }""";
   }
   td.td4 {
      background: $*gradient_4"""; if ($*blockbg_4 != "") { """ url($*blockbg_4) center center"""; }""";
   }
   td.td5 {
      background: $*gradient_5"""; if ($*blockbg_5 != "") { """ url($*blockbg_5) center center"""; }""";
   }
   td.td6 {
      background: $*gradient_6"""; if ($*blockbg_6 != "") { """ url($*blockbg_6) center center"""; }""";
   }
   div.contentbody {
      min-height: 175px;
      margin: 0 25px 0 0;
      padding: 10px 20px 10px 10px;
      background: $*entry_bgcolor;
      line-height: $*entry_line_height;""";
      if ($*edge_transparency == true) {
         """border: $*border_width $*border_style $*edge_border_color;""";
      }
      """text-align: $*text_align;
   }
   * html div.contentbody {
      height: 175px;
   }

/* Entry and comment metadata */

div.entrymeta {
      min-height: 100px;
      margin: 0 0 10px 0;""";
      if ($*meta_font_size != "same") {
         """font-size: $*meta_font_size;""";
      }
      """line-height: 120%;
      text-align: left;
   }
   div.entrymeta td {
      vertical-align: top;
   }
   div.entrymeta td img {
      vertical-align: top;
   }
   * html div.entrymeta {
      height: 100px;
   }
   div.entrymeta a, div.entrymeta a:visited {
      color: $*entry_fgcolor;
   }
   div.entrymeta a:hover, div.entrymeta a:active {
      color: $*hlink_color;
   }
   div.userpic {
      width: 100px;
      height: 100px;
      margin: 0 10px 0 0;
      float: left;
      text-align: center;
   }
   div.userpic img {
      border: 0;
   }
   td.metatitle {
      padding: 0 5px 0 0;
      font-weight: 700;
   }

/* Comment links */

div.commentlinks {
      margin: 5px 0 0 0;""";
      if ($*meta_font_size != "same") {
         """font-size: $*meta_font_size;""";
      }
      """text-align: right;
   }
   div.comment {
      padding: 0 0 0 5px;
      margin: 0 0 5px 0;
      border-left: 1px $*border_style $*edge_border_color;
      border-bottom: 1px $*border_style $*edge_border_color;
   }

/* Navigation boxes */

div.navholder {
      background: $*edge_bgcolor;""";
      if ($*edge_transparency == false) {
         """border: $*border_width $*border_style $*edge_border_color;""";
      }
      """width: $entry_width;
      margin: 0 $margin_right 10px $margin_left;
   }

div.navbody {
      margin: 0 25px 0 0;
      padding: 10px 15px 10px 10px;
      background: $*entry_bgcolor;
      text-align: center;""";
      if ($*edge_transparency == true) {
         """border: $*border_width $*border_style $*edge_border_color;""";
      }
   """}
   * html div.navbody {
      margin: 0 42px 0 0;
   }
   div.nextlink {
      margin: 0;
      float: right;
   }
   div.prevlink {
      margin: 0;
      float: left;
   }

/* Year page */

table.month {
      width: 100%;
      text-align: center;
   }
   td.dayfullwith {
      padding: 2px 0 2px 0;
      background: $*withdays_bgcolor;
      border: 1px $*border_style $*edge_border_color;
   }
   td.dayfullwithout {
      padding: 2px 0 2px 0;
      background: $*withoutdays_bgcolor;
      border: 1px $*border_style $*edge_border_color;
   }
   td.dayfullwith hr, td.dayfullwithout hr {
      height: 1px;
      width: 75%;
      background: $*edge_border_color;
      color: $*edge_border_color;
      border: 0;
   }
   td.dayempty {
      padding: 2px 0 2px 0;

border: 0;
   }

/* Month page */

table.subjects {
      width: 100%;
   }
   td.monthdays {
      padding: 5px 0 0 0;
      vertical-align: top;
      border: 0;
   }
   td.monthsubjects {
      padding: 0;
      background: $*month_subjects_bgcolor;
      border: 1px $*border_style $*edge_border_color;
      text-align: left;
   }
   td.monthsubjects dl {
      margin: 5px;
   }

/* Comment mass action */
   div.multiform {""";
      if ($*meta_font_size != "same") {
         """font-size: $*meta_font_size;""";
      }
      """text-align: center;
   }

/* Reply form */
   textarea.textbox {
      width: 100%;
      background: $*entry_bgcolor;
      color: $*entry_fgcolor;
   }
   input {
      background: $*entry_bgcolor;
      color: $*entry_fgcolor;
   }

/* Adv */
   .j-adv {
        margin: 20px auto;
        text-align: center;
        }
        .j-adv-inner {
            display: inline-block;
            }

.html-mobile .commentlinks__link--duplicate,
   .html-mobile .commentlinks__link--duplicate + .commentlinks__divider {
        display: none !important;
        }
   """;

print_custom_control_strip_css();
   appended_to_stylesheet();
}

################################################################################
#
# Global Functions
#

function lay_render_nav_box_top() : string {
   return """<div class="navholder">
      <div class="navbody">""";
}
function lay_nav_box_top() {
   print lay_render_nav_box_top();
}

function lay_render_nav_box_bottom() : string {
   return """</div>
   </div>""";
}

function lay_nav_box_bottom() {
   print lay_render_nav_box_bottom();
}

function lay_content_box_top() {
   """<div class="contentholder">
      <table class="contentgradient">
         <tr>
            <td class="td1"> </td>
         </tr>
         <tr>
            <td class="td2"> </td>
         </tr>
         <tr>
            <td class="td3"> </td>
         </tr>
         <tr>
            <td class="td4"> </td>
         </tr>
         <tr>
            <td class="td5"> </td>
         </tr>
         <tr>
            <td class="td6"> </td>
         </tr>
      </table>
      <div class="contentbody s2-entrytext">""";
}

function lay_content_box_bottom() {
   """</div>
   </div>""";
}

################################################################################
#
# Page
#

function Page::lay_print_header() {
   var string block_size;
   if ($*head_size == "small") {
      $block_size = "50px";
   }
   elseif ($*head_size == "medium") {
      $block_size = "75px";
   }
   else {
      $block_size = "100px";

}

var string title = $.global_title;
   var string subtitle = $.global_subtitle;
   var Link mems_link  = $.journal->get_link("memories");
   var Link todo_link  = $.journal->get_link("todo");
   var Link update_link = $.journal->get_link("post_entry");

var string{} view_url = { # make hash of urls
                            "recent"    => $.view_url{"recent"},
                            "friends"   => $.view_url{"friends"},
                            "archive"   => $.view_url{"archive"},
                            "userinfo"  => $.view_url{"userinfo"},
                            "tags"      => $.view_url{"recent"} + "tag/",
                            "userpics"  => $.journal.userpic_listing_url,
                            "memories"  => $mems_link.url,
                            "todo"      => $todo_link.url,
                            "update"    => $update_link.url,
                            "website"   => $.journal.website_url,
                            "scrapbook" => "http://pics.livejournal.com/$.journal.username/",
   };

var string{} view_text = { # make hash of texts
                             "recent"    => lang_viewname("recent"),
                             "friends"   => lang_viewname("friends"),
                             "archive"   => lang_viewname("archive"),
                             "userinfo"  => lang_viewname("userinfo"),
                             "tags"      => lang_viewname("tags"),
                             "userpics"  => "User Pictures",
                             "memories"  => "Memories",
                             "todo"      => "To-Do List",
                             "update"    => "Update Journal",
                             "website"   => $.journal.website_name != "" ? $.journal.website_name : $*text_website_default_name,
                             "scrapbook" => "ScrapBook",
   };

# array that states in what order to print the blocks
   var string[] views_order = ["recent", "friends", "archive", "userinfo"];

# add fifth block link
   # if set to website but no website, use tags
   if ($*fifth_block_link == "website" and $view_url{"website"} == "") {
      $views_order[size $views_order] = "tags";
   } else {
      $views_order[size $views_order] = $*fifth_block_link;
   }

# add sixth block link
   # if set to website but not website, use todo
   if ($*sixth_block_link == "website" and $view_url{"website"} == "") {
      $views_order[size $views_order] = "todo";
   } else {
      $views_order[size $views_order] = $*sixth_block_link;
   }

# create var for block id number
   var int id_num = 1;

"""
   <div id="header">
   """;

if ($*show_title) {
      print safe """<div id="title">$title""";
      if($subtitle != "") {
         print safe """<br /><span id="subtitle">$subtitle</span>""";
      }
      "</div>";
   }

"""
   </div>
   <table id="gradient">
      <tr>""";

foreach var string v ($views_order) {
      if ($view_url{$v} != "") {
         print safe """
            <td class="gradient" id="td$id_num"><a href="$view_url{$v}" title="$view_text{$v}"><img src="$*IMGDIR/dot.gif" height="$block_size" width="$block_size" alt="$view_text{$v}" /></a></td>""";
         $id_num++;
      }
   }
   """
      </tr>
   </table>
""";
}

function Page::lay_entrymeta (Entry e) {
   var string subject = $e.subject !="" ? $e->plain_subject() : $*text_nosubject;

if (defined $e.userpic and (
      $*show_entry_userpic
      or ($e.poster.username != $.journal.username and $e.userpic.url != $.journal.default_pic.url)
      or $.view == "friends"
      or $.view == "entry")) {
         """<div class="userpic"><a href="$*SITEROOT/allpics.bml?user=$e.poster.username" title="User Pictures for $e.poster.username"><img src="$e.userpic.url" width='""";print $e.userpic.width;"""px' height='""";print $e.userpic.height;"""px' alt="" /></a></div>""";
   }
   print safe """<div class="entrymeta"><table cellpadding="0" cellspacing="0">
      <tr>
         <td class="metatitle">Title:</td> <td><a href="$e.permalink_url">$subject</a></td>
      </tr>""";
      if ($e.tags) {
           print safe """<tr>
              <td class="metatitle">$*text_tags:</td>  <td>""";
               var int tcount = 0;
             foreach var Tag t ($e.tags) {
                    $tcount++;
                    if ($tcount != size $e.tags) { """<a rel="tag" href="$t.url">$t.name</a>, """; }
                    else { """<a class="tag" href="$t.url">$t.name</a>"""; }
                 }
           """</td></tr>""";
        }
       if ($e.poster.username != $.journal.username
         or $.view == "friends") {
            """<tr>
               <td class="metatitle">Author:</td> <td>""";
                  if ($*lj_user_tags == false){
                     """<a href='"""; print $e.poster->base_url(); """'>$e.poster.username</a>""";
                  }
                  else {
                     """$e.poster""";
                  }
                  if ($e.poster.username != $e.journal.username) {
                """ posting in """;

if ($*lj_user_tags == false) {
                        """<a href='"""; print $e.journal->base_url(); """'>$e.journal.username</a>""";
                     }
                     else {
                        """$e.journal""";
                     }
                  }
                  """</td>
               </tr>
               """;
      }
   """<tr>
      <td class="metatitle">Date:</td> <td>""";lay_historylink($e);"""$*datedivider""";print $e.time->time_format($*timeformat);"""</td>
        </tr>
        <tr>
           <td class="metatitle">Security:</td> <td>""";
           if ($e.security != "" or $e.sticky or $e.delayed) {
              if ($e.delayed) { " $e.delayed_icon"; }
              if ($e.sticky) { " $e.sticky_icon"; }
              if ($e.security) { " $e.security_icon"; }
           }
           else {
              """public""";
           }
           """</td>
        </tr>""";
        if (size $e.metadata{"groups"}) {
           print safe """<tr>
              <td class="metatitle">$*text_meta_groups:</td> <td>$e.metadata{"groups"}</td>
           </tr>""";
        }
        if (size $e.metadata{"location"}) {
           print safe """<tr>
              <td class="metatitle">$*text_meta_location:</td> <td>$e.metadata{"location"}</td>
           </tr>""";
        }
        if (size $e.metadata{"music"}) {
           print safe """<tr>
              <td class="metatitle">$*text_meta_music:</td> <td>$e.metadata{"music"}</td>
           </tr>""";
        }
        if (size $e.metadata{"mood"}) {
           print safe """<tr>
              <td class="metatitle">$*text_meta_mood:</td> <td>$e.metadata{"mood"}""";
              if ((defined $e.mood_icon)
                 and ($*mood_icons == true)) {
                 """ $e.mood_icon """;
              }
              """</td>
            </tr>""";
        }
   """</table></div>""";
}

function CommentInfo::print() {
   if ($.enabled) {
      if ($.count > 0 or $.screened) {
         $this->print_readlink();
      }
      $this->print_postlink();
   }
}

function CommentInfo::print_readlink() {
   var Page p = get_page();
   if ($.count > 0 or $.screened) {
      print safe """<a href="$.read_url">""" +
      get_plural_phrase($.count, $p.view == "friends" ? "text_read_comments_friends" : "text_read_comments") +
      """</a> $*comment_link_divider """;
   }
}

function CommentInfo::print_postlink() {
   var Page p = get_page();
   var string linktext = ( $p.view == "friends" ? $*text_post_comment_friends : $*text_post_comment );
   var string target = "topcomment";
if (not $.locked) {
   $p->print_reply_link({"target" => $target, "class" => "comments", "title" => "$linktext", "linktext" => $linktext, "reply_url" => $.post_url});
}
   $p->print_reply_container({"target" => $target});
}

function Page::print_linklist() {
    var string links_title = "Links";
    var string links_sep = " :: ";

if ($*linklist_support and size $.linklist > 0) {
        var string linklist = "";
        var string link = "";
        var bool section_open = false;
        var bool first = true;

foreach var UserLink l ($.linklist) {
            if ($l.title) {
                if ($l.is_heading or $first) {
                    if ($section_open) {
                        $linklist = $linklist + "<br />";
                    }
                    if ($l.is_heading) {
                        $link = """$l.title""";
                    } else {
                        $link = """$links_title$links_sep<a href="$l.url" $l.attributes>$l.title</a>""";
                    }
                    $section_open = true;
                    $first = false;
                } else {
                    $link = """$links_sep<a href="$l.url" $l.attributes>$l.title</a>""";
                }
            } else {
                $link = "<br />";
            }
            $linklist = $linklist + $link;
        }
        if ($linklist != "") {
            """<div class="navholder"><div class="navbody">$linklist</div></div>""";
        }
    }
}

function Page::print_entry (Entry e){
   var Page p = get_page();
   lay_content_box_top();
   $this->lay_entrymeta($e);
   $e->print_text();
   var string divider = $*comment_link_divider;

if ($divider) {
      $divider = """<span class="commentlinks__divider">$divider</span>""";
   }

var string{} link_caption = {
      "edit_entry" => $*text_editlink,
      "edit_tags" => $*text_edittagslink,
      "mem_add" => $*text_memlink,
      "share" => $*text_share,
      "flag" => $*text_flag,
      "watch_comments" => $*text_tracklink,
      "unwatch_comments" => $*text_untracklink,
   };
   var Link link;
   var string url;
   var string text;
   var string link_extra;

"""<div class="commentlinks">$divider """;
   foreach var string link_key ($e.link_keyseq) {
      $link = $e->get_link($link_key);
      $url = $link.url;
      $text = $link_caption{$link_key} != "" ? $link_caption{$link_key} : $link.caption;
      $link_extra = get_extra( $link.extra );
      if (defined $link) {
         print safe """<a class="commentlinks__link commentlinks__link--$link_key" href="$url" $link_extra>$text</a> $divider """;
         $link->print_raw();
      }
   }

var string comments_showspam = "";
   if ($e.comments.spam_counter > 0 and $e.comments.read_spam_url != "") {
      if ($p.showspam) {
         $comments_showspam = get_plural_phrase($e.comments.spam_counter, "text_read_spam_comments") + """</span> $divider """;
      } else {
         $comments_showspam = """<a href=\"$e.comments.read_spam_url\">""" + get_plural_phrase($e.comments.spam_counter, "text_read_all_spam_comments") + """</a></span> $divider """;
      }
   }
   if ($p.view == "entry") {print safe "$comments_showspam";}

$e.comments->print();
   """</div>""";
   lay_content_box_bottom();
}

function Page::print()  {
   var string title = $.global_title;
   var string subtitle = $.global_subtitle;
   var string view_title = $this->view_title() != "" ? $this->view_title() : "Unknown View";

"""<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
   <html xmlns="http://www.w3.org/1999/xhtml" class="html-s2-no-adaptive">
   <head>
     <meta http-equiv="X-UA-Compatible" content="IE=EmulateIE7; IE=EmulateIE9" />
   """;
         $this->print_head();
         $this->print_stylesheets();
         println safe """<title>$title :: $view_title</title>""";
   """</head>
   <body>""";
   $this->print_control_strip();
   $this->print_pagewide_slot();

"""<div class="wrapper">""";

$this->lay_print_header();
      if ( viewer_sees_ad_box("s2.vertical") ) {
         """<table width="100%" height="100%">""";
         """<tr><td valign="top">""";
      }
      $this->print_linklist();
      $this->print_body();

if ( viewer_sees_ad_box("s2.bottom") ) {
         """<div class="j-adv j-bottom-adv">
             <div class="j-adv-inner">""";
                 $this->print_ad_box("s2.bottom");
         """</div>
         </div>""";
      }

if ( viewer_sees_ad_box("s2.vertical") ) {
         "</td>";
         """<td valign="top" align="right" width="20%">""";
         """<div style="margin-right: 10px;">""";
         """<div class="box-vertical1">""";
            $this->print_ad_box("s2.vertical");
         """</div>""";
         "</div></td></tr></table>";
      }
   """</div>
   </body>
   </html>""";
}

################################################################################
#
# Entry Page
#

function EntryPage::lay_render_nav() : string {
   var string ret = "";
   var Link prev = $.entry->get_link("nav_prev");
   var Link next = $.entry->get_link("nav_next");

$ret = $ret + lay_render_nav_box_top();

if ($prev.url != "") {
      $ret = $ret + """<div class="prevlink"><a href="$prev.url")">$*text_prevlink</a></div>""";
   }
   if ($next.url != "") {
      $ret = $ret + """<div class="nextlink"><a href="$next.url")">$*text_nextlink</a></div>""";
   }
   var int itemid = $this.entry.itemid/256;
   $ret = $ret + """Entry #$itemid""";

$ret = $ret + lay_render_nav_box_bottom();

return $ret;
}

function EntryPage::lay_print_nav() {
   print $this->lay_render_nav();
}

function ItemRange::print() {
   if ($.all_subitems_displayed) { return; }
   lay_nav_box_top();
   print lang_page_of_pages($.current, $.total);
   foreach var int i (1..$.total) {
      if ($i == $.current) {
         """ $*link_divider $i""";
      }
      else {
         var string subitem_url = $this->url_of($i);
          """ $*link_divider <a href="$subitem_url">$i</a>""";
      }
   }
   lay_nav_box_bottom();
}

function EntryPage::lay_render_commentmeta (Comment c) : string {
   var string subject = $c.subject !="" ? $c.subject : $*text_nosubject;
   var string keywords = $c.metadata{"picture_keyword"} !="" ? $c.metadata{"picture_keyword"} : "(default)";

var string ret = "";

if (defined $c.userpic) {
      $ret = $ret + """<div class="userpic"><a href="$*SITEROOT/allpics.bml?user=$c.poster.username"><img src="$c.userpic.url" width='""";
      $ret = $ret + $c.userpic.width;
      $ret = $ret + """px' height='""";
      $ret = $ret + $c.userpic.height;
      $ret = $ret + """px' title="$c.poster.username: $keywords" alt="" /></a></div>""";
   }
   $ret = $ret + """<div class="entrymeta"><table cellpadding="0" cellspacing="0">
      <tr>
         <td class="metatitle">Title:</td> <td><a href="$c.permalink_url">$subject</a>""";
            if (defined $c.subject_icon
               and ($*subject_icons == true)) {
                  $ret = $ret + """ $c.subject_icon""";
            }
      $ret = $ret + """</td>
      </tr>
      <tr>
         <td class="metatitle">Author:</td> <td>""";
         if (defined $c.poster) {
            if ($*lj_user_tags == false) {
               $ret = $ret + """<a href='""";
               $ret = $ret +  $c.poster->base_url();
               $ret = $ret + """'>$c.poster.username</a>""";
            }
            else {
               $ret = $ret + """$c.poster""";
            }
         }
         else {
            $ret = $ret + """$*text_poster_anonymous""";
         }
         $ret = $ret + """</td>
      </tr>
      <tr>
         <td class="metatitle">Date:</td> <td>""";
         $ret = $ret + $c->time_display($*dateformat, $*timeformat);
         $ret = $ret + """</td>
      </tr>
      <tr>
         <td class="metatitle">Status:</td> <td>""";

var string{} link_caption = {
               "delete_comment" => "Delete?",
               "screen_comment" => "Not Screened",
               "unscreen_comment" => "Screened",
               "freeze_thread" => "Not Frozen",
               "unfreeze_thread" => "Frozen",
               "watch_thread" => "Track?",
               "unwatch_thread" => "Tracking",
               "watching_parent" => "Tracking Parent",
            };
            var bool first_link = true;
            var Link link;
            var string url;
            var string text;

foreach var string link_key ($c.link_keyseq) {
               $link = $c->get_link($link_key);
               # $url = $link.url;
               # $text = $link_caption{$link_key} != "" ? $link_caption{$link_key} : $link.caption;
               if ($first_link and defined $link) {
        $url = $link.url;
        $text = $link_caption{$link_key} != "" ? $link_caption{$link_key} : $link.caption;
                  $ret = $ret + """<a href="$url">$text</a>""";
                  $first_link = false;
               } elseif (defined $link) {
        $url = $link.url;
        $text = $link_caption{$link_key} != "" ? $link_caption{$link_key} : $link.caption;
                  $ret = $ret + """ $*link_divider <a href="$url">$text</a>""";
               }
            }

if ($this.multiform_on) {
               $ret = $ret + " ";
               $ret = $ret + $c->print_multiform_check({ "render" => "1" });
            }
         $ret = $ret + """</td>
      </tr>""";
      if ($c.metadata{"poster_ip"}) {
         $ret = $ret + """<tr>
            <td class="metatitle">IP Address:</td> <td>""";
            $ret = $ret + $c.metadata{"poster_ip"};
            $ret = $ret + """</td>
         </tr>""";
      }
   $ret = $ret + """</table></div>""";
   return $ret;
}

function EntryPage::lay_commentmeta (Comment c) {
   print $this->lay_render_commentmeta($c);
}

function EntryPage::render_comment (Comment c, int _show_expand_collapse) : string {
    var Page p = get_page();
    var string indent = ($c.depth - 1) * 15 + "px";
    var string ret = "";

if ($_show_expand_collapse == 1) {
      $c._show_expand_collapse = 1;
    }

$ret = $ret + """<div id="$c.dom_id" class="comment" style="margin-left: $indent;"><a name="$c.anchor"></a>""";

if (($c.spam) and (not $p.showspam) and (not $c.can_marked_as_spam) and (size($c.replies) > 0)) {
        $ret = $ret + """<strong>$*text_spam_comment</strong>""";
    } elseif ($c.screened and not viewer_is_owner()) {
        $ret = $ret + """$*text_comment_screened""";
    } elseif ($c.deleted) {
        $ret = $ret + """$*text_comment_deleted""";
    } elseif ($c.full) {
        $ret = $ret + $this->render_comment_full($c);
    } else {
        $ret = $ret + $this->render_comment_partial($c);
    }

$ret = $ret + """</div>""";
    return $ret;
}

function EntryPage::print_comment (Comment c) {
    print $this->render_comment ($c, 0);
}

function EntryPage::render_comment_full (Comment c) : string {
    var string ret = "";

$ret = $ret + $this->lay_render_commentmeta($c);

$ret = $ret + $c->render_text();
    $ret = $ret + """<div class="commentlinks">$*comment_link_divider """;

if ($c.thread_url != "") {
        $ret = $ret + """<a href="$c.thread_url">Thread</a> $*comment_link_divider """;
    }
    if ($c.parent_url != "") {
        $ret = $ret + """<a href="$c.parent_url">Parent</a> $*comment_link_divider """;
    }
    if (not $c.frozen) {
        $ret = $ret + $c->print_reply_link({"linktext" => $*text_comment_reply, "render" => "1"});
    }

$ret = $ret + $c->print_expand_collapse_links({ "expand"=>" $*comment_link_divider %_", "collapse"=>" $*comment_link_divider %_", "render" => "1" });
    $ret = $ret + """</div>""";
    $ret = $ret + $c->print_reply_container({"render" => "1"});

return $ret;
}

function EntryPage::print_comment_full (Comment c) {
    print $this->render_comment_full($c);
}

function EntryPage::render_comment_partial (Comment c) : string {
    #var string poster = defined $c.poster ? "<a href=\"" + $c.poster->base_url() + "\">$c.poster.username</a>" : """<em class="noposter">$*text_poster_anonymous</em>""";
    var string poster = defined $c.poster ? $c.poster->as_string() : """<em class="noposter">$*text_poster_anonymous</em>""";
    var string subj = $c.subject != "" ? $c.subject : """<em class="nosubject">$*text_nosubject</em>""";
    var string subj_sep = "by";
    var string sep = "::";
    var string ret = "";

$ret = $ret + """<a href="$c.permalink_url">$subj</a> $subj_sep $poster """;
    $ret = $ret + $c->print_expand_collapse_links({ "expand"=>" $sep %_", "collapse"=>" $sep %_", "render" => "1" });

return $ret;
}

function EntryPage::print_comment_partial (Comment c) {
    print $this->render_comment_partial ($c);
}

function EntryPage::print_body {
   $this->lay_print_nav();
   $this->print_entry($.entry);

if ( viewer_sees_ad_box( "s2.after.single.post" ) ){
        """<div class="j-adv j-after-single-post-adv">
            <div class="j-adv-inner">""";
                $this->print_ad_box( "s2.after.single.post" );
        """</div>
        </div>""";
    }

if ($.entry.comments.enabled) {
      """<span id="$*text_comments_id"></span>""";
      if ($.comment_pages.total_subitems > 0) {
         $.comment_pages->print();
      }
      if (($.entry.comments.count > 0) or $.entry.comments.screened) {
         lay_content_box_top();
         if ($this.multiform_on) {
            $this->print_multiform_start();

}
         $this->print_comments($.comments);
         if ($this.multiform_on) {
        """<div class="multiform">"""; $this->print_multiform_actionline(); """</div>""";
        $this->print_multiform_end();
     }
         lay_content_box_bottom();
      }
   }
   $this->lay_print_nav();
}

################################################################################
#
# Reply Page
#

function ReplyPage::lay_print_nav() {
   var EntryLite el = $.replyto;
   lay_nav_box_top();
   var Link prev = $.entry->get_link("nav_prev");
   var Link next = $.entry->get_link("nav_next");
   if ($prev.url != "") {
      print safe """<div class="prevlink"><a href="$prev.url")">$*text_prevlink</a></div>""";
   }
   if ($next.url != "") {
      print safe """<div class="nextlink"><a href="$next.url")">$*text_nextlink</a></div>""";
   }
   var int itemid = $this.entry.itemid/256;
   if ($el.depth == 0) {
      """Reply to Entry #$itemid""";
   }
   else {
      """Reply to Comment on Entry #$itemid""";
   }
   lay_nav_box_bottom();
}

function ReplyPage::lay_replytometa(Page p, Entry e, EntryLite el) {
   var string subject = $el.subject !="" ? $el.subject : $*text_nosubject;
   var Comment c;
   var string keywords = $el.metadata{"picture_keyword"} !="" ? $el.metadata{"picture_keyword"} : "(default)";
   var string ip = $c.metadata{"poster_ip"};

if (defined $el.userpic) {

"""<div class="userpic"><a href="$*SITEROOT/allpics.bml?user=$el.poster.username"><img src="$el.userpic.url" width='""";print $el.userpic.width;"""px' height='""";print $el.userpic.height;"""px' title="$el.poster.username: $keywords" alt="" /></a></div>""";
   }
   print safe """<div class="entrymeta"><table cellpadding="0" cellspacing="0">
      <tr>
         <td class="metatitle">Subject:</td> <td><a href="$el.permalink_url">$subject</a>""";
            if (defined $c.subject_icon
               and ($*subject_icons == true)) {
                  """ $c.subject_icon""";
            }
         """</td>
      </tr>
      <tr>
         <td class="metatitle">Author:</td> <td>""";
         if (defined $el.poster) {
            """<a href='""";print $el.poster->base_url();"""'>$el.poster.username</a>""";
         }
         else {
            print safe """$*text_poster_anonymous""";
         }
         """</td>
      </tr>
      <tr>
         <td class="metatitle">Date:</td> <td>""";print $el.time->date_format($*dateformat);"""$*datedivider""";print $el.time->time_format($*timeformat);"""</td>
      </tr>""";
    if ($ip) {
       """<tr>
          <td class="metatitle">IP Address:</td> <td>$ip</td>
       </tr>""";
    }
   """</table></div>""";
}

function ReplyPage::lay_print_replyto(Page p, Entry e, EntryLite el) {
   var Comment c;
   if ($el.depth != 0) {

lay_content_box_top();
      """<div class="comment">""";
         $this->lay_replytometa($this, $.entry, $.replyto);
         $.replyto->print_text();
         """
         <div class="commentlinks">$*comment_link_divider """;
            if ($c.thread_url != "") {
               """<a href="$c.thread_url">Thread</a> $*comment_link_divider """;
            }
            if ($c.parent_url != "") {
               """<a href="c.parent_url">Parent</a> $*comment_link_divider """;
            }
            if (not $c.frozen) {
               """<a href="$c.reply_url">Reply</a> $*comment_link_divider""";
            }
         """</div>
      </div>""";
      lay_content_box_bottom();
   }
}

function ReplyPage::print_body() {
   $this->lay_print_nav();
   $this->print_entry($.entry);
   """<div style="margin: 0px 10% 10px 20%; width:65%;">""";
   $.entry->print_ebox();
   "</div>";
   """<span id="$*text_addcomment_id"></span>""";
   if (not $.entry.comments.enabled) {
      lay_nav_box_top();
      print safe """$*text_reply_nocomments""";
      lay_nav_box_bottom();
   }
   else {
      $this->lay_print_replyto($this, $.entry, $.replyto);
      lay_content_box_top();
      $.form->print();
      lay_content_box_bottom();
   }
   $this->lay_print_nav();
}

################################################################################
#
# RecentPage
#

function RecentPage::lay_print_nav() {

lay_nav_box_top();
   if ($.nav.backward_url != "") {
      print safe """<div class="prevlink"><a href="$.nav.backward_url">$*text_prevlink</a></div>""";
   }
   if ($.nav.forward_url != "") {
      print safe """<div class="nextlink"><a href="$.nav.forward_url">$*text_nextlink</a></div>""";
   }
   var int start = $.nav.skip;
   var int skip = size $.entries;
   var int end = $.nav.skip + size $.entries;
   """$skip Recent Entries ($start Skipped)""";
   """ """;
   lay_nav_box_bottom();
}

function RecentPage::print_body {
   $this->lay_print_nav();
   foreach var Entry e ($.entries) {

if (not $e.promo) { # LJSUP-26382

$this->print_entry($e);
         if ($e->viewer_sees_ebox()) {
            """<div style="margin:0 10% 10px 20%; width:65%; text-align:center;">""";
            $e->print_ebox();
            "</div>";
         }

}

}
   $this->lay_print_nav();
}

################################################################################
#
# FriendsPage
#

function FriendsPage::lay_print_nav() {
   lay_nav_box_top();
   if ($.nav.backward_url != "") {
      print safe """<div class="prevlink"><a href="$.nav.backward_url">$*text_prevlink</a></div>""";
   }
   if ($.nav.forward_url != "") {
      print safe """<div class="nextlink"><a href="$.nav.forward_url">$*text_nextlink</a></div>""";
   }
   var int start = $.nav.skip;
   var int skip = size $.entries;
   var int end = $.nav.skip + size $.entries;
   """$skip Friends' Entries ($start Skipped)""";
   lay_nav_box_bottom();
}

function FriendsPage::print_body {
   $this->lay_print_nav();
   foreach var Entry e ($.entries) {
      if (not $e.promo) { # LJSUP-26382
         $this->print_entry($e);
         if ($e->viewer_sees_ebox()) {
            """<div style="margin:0px 10% 10px 20%; width: 65%; text-align: center">""";
            $e->print_ebox();
            "</div>";
         }
      }
   }
   $this->lay_print_nav();
}

################################################################################
#
# YearPage
#

function YearPage::print_year_links() {
   """$*link_divider """;
   foreach var YearYear y ($.years) {
      if ($y.displayed) {
         """$y.year $*link_divider """;
      }
      else {

"""<a href="$y.url">$y.year</a> $*link_divider """;
      }
   }
}

function YearPage::lay_print_nav() {
   lay_nav_box_top();
   $this->print_year_links();
   lay_nav_box_bottom();
}

function YearWeek::print() {
   """<tr>""";
   var YearDay[] theDays = $.days;
   var int pre = $.pre_empty;
   foreach var int i (1..$pre) {
      """<td class="empty"> </td>""";
   }
   foreach var YearDay d ($theDays) {
      var int num = $d.num_entries;
      if ($num > 0) {
         """<td class="dayfullwith">$d.date.day<br /><hr /><a href="$d.url">$num</a>""";
      }
      else {
         """<td class="dayfullwithout">$d.date.day<br /><hr /> """;
      }
      """</td>""";
   }
   var int post = $.post_empty;
   foreach var int i (1..$post) {
      """<td class="dayempty"> </td>""";
   }
   """</tr>""";
}

function YearPage::print_month(YearMonth m) {
   lay_content_box_top();
   """<table class="entrymeta">
      <tr>
         <td class="metatitle">Month:</td> <td><a href="$m.url">"""; print $m->month_format(); """</a></td>
      </tr>
   </table>
   <table class="month">""";
   foreach var YearWeek w ($m.weeks) {
      $w->print();
   }
   """</table>""";
   lay_content_box_bottom();
}

function YearPage::print_body() {
   $this->lay_print_nav();
   if ($*page_year_sortorder == "forward") {
      foreach var YearMonth m ($.months) {
         if ($m.has_entries) {
            $this->print_month($m);
         }
      }
   }
   elseif ($*page_year_sortorder == "reverse") {
      foreach var YearMonth m (reverse $.months) {
         if ($m.has_entries) {
            $this->print_month($m);
         }
      }
   }
   $this->lay_print_nav();
}

################################################################################
#
# MonthPage
#

function MonthPage::lay_print_nav() {
   lay_nav_box_top();
   if ($.prev_url != "") {
      print safe """<div class="prevlink"><a href="$.prev_url">$*text_prevlink</a></div>""";
   }
   if ($.next_url != "") {
      print safe """<div class="nextlink"><a href="$.next_url">$*text_nextlink</a></div>""";

}
   """<form method="post" action="$.redir.url">""";
      $.redir->print_hiddens();
      if (size $.months > 1) {
         """<select name="redir_key">""";
         foreach var MonthEntryInfo mei ($.months) {
            var string sel;
            if ($mei.date.year == $.date.year and $mei.date.month == $.date.month) {
               $sel = " selected='selected'";
            }
            """<option value="$mei.redir_key"$sel>""";print $mei.date->date_format($*lang_fmt_month_long);"""</option>""";
         }
         """</select>
            <input type="submit" value="View" />""";
      }
      """</form>""";
   lay_nav_box_bottom();
}

function MonthDay::print_subjectlist() {
   """<dl>""";
   foreach var Entry e ($.entries) {
      """<dt>""";
      if ($e.subject != "") {
         """<a href="$e.permalink_url">$e.subject</a>""";
      }
      else {
         print safe """<a href="$e.permalink_url">$*text_nosubject</a>""";
      }
      """</dt>
      <dd>""";

if ($e.delayed) { "$e.delayed_icon "; }
      if ($e.sticky) { "$e.sticky_icon "; }
      if ($e.security) { "$e.security_icon "; }

""" entry posted """;
      if ($e.poster.username != $e.journal.username) {
         """by <a href="""; print $e.poster->base_url(); """>$e.poster.username</a> """;
      }
      """at """;
      print $e.time->time_format("$*timeformat");
      if ($e.comments.count > 0) {
         print safe " with " + get_plural_phrase($e.comments.count, "text_read_comments");
      }
      if ($e.comments.screened) {
         print safe """ $*text_month_screened_comments""";
      }
      """</dd>""";
   }
   """</dl>""";
}

function MonthPage::print_body {
   $this->lay_print_nav();
   lay_content_box_top();
   """<table class="entrymeta">
      <tr>
         <td class="metatitle">Month:</td> <td>"""; print $.date->date_format($*lang_fmt_month_long); """</td>
      </tr>
   </table>
   <table class="subjects" cellpadding="0">""";
   foreach var MonthDay d ($.days) {
      if ($d.has_entries) {
         """<tr>
            <td class="monthdays"><a href="$d.url">""";
            print lang_ordinal($d.day);
            """</a></td>
            <td class="monthsubjects">""";
            $d->print_subjectlist();
            """</td>
         </tr>""";
      }
   }
   """</table>""";
   lay_content_box_bottom();
   $this->lay_print_nav();
}

################################################################################
#
# DayPage
#

function DayPage::lay_print_nav() {
   lay_nav_box_top();
   if ($.prev_url != "") {
      print safe """<div class="prevlink"><a href="$.prev_url">$*text_prevlink</a></div>""";
   }
   if ($.next_url != "") {
      print safe """<div class="nextlink"><a href="$.next_url">$*text_nextlink</a></div>""";
   }
   print $.date->date_format("$*lang_fmt_date_long_day");
   lay_nav_box_bottom();
}

function DayPage::print_body {
   $this->lay_print_nav();
   if ($.has_entries) {
      if ($*page_day_sortorder == "forward") {
         foreach var Entry e ($.entries) {
            $this->print_entry($e);
            if ($e->viewer_sees_ebox()) {
                """<div style="margin:0px 10% 10px 20%; width: 65%; text-align: center;">""";
                $e->print_ebox();
                "</div>";
            }
         }
      }

elseif ($*page_day_sortorder == "reverse") {
         foreach var Entry e (reverse $.entries) {
            $this->print_entry($e);
            if ($e->viewer_sees_ebox()) {
                """<div style="margin-bottom: 10px; text-align: center;">""";
                $e->print_ebox();
                "</div>";
            }
         }
      }
   }
   else {
      lay_content_box_top();
      """<div class="entrymeta"><table cellpadding="0" cellspacing="0">
         <tr>
            <td class="metatitle">Date:</td> <td>""";print $.date->date_format($*dateformat);"""</td>
         </tr>
      </table></div>""";
      print safe $*text_noentries_day;
      lay_content_box_bottom();
   }
   $this->lay_print_nav();
}

################################################################################
#
# TagsPage
#

function TagsPage::lay_print_nav() {
   lay_nav_box_top();
      print safe """$*text_tags_description""";
   lay_nav_box_bottom();
}

function TagsPage::print_body() {
   $this->lay_print_nav();
   lay_content_box_top();

#   var string taglist = visible_tag_list(TagDetail td);
   if ($.tags) {
      """<dl>""";
         foreach var TagDetail td ($.tags) {
            var string uses = get_plural_phrase($td.use_count, "text_tag_uses");
            var int customcount = $td.use_count - ($td.security_counts{"public"} + $td.security_counts{"friends"} + $td.security_counts{"private"});
            print safe """<dt><a href="$td.url">$td.name</a></dt>
               <dd>$uses: $td.security_counts{"public"} public, $td.security_counts{"friends"} friends-only, $customcount custom, $td.security_counts{"private"} private</dd>""";
         }
      """</dl>""";
   }
   else {
      """No topics to display.  Either this user has not assigned topics to any entries, or all of the assigned topics are on entries you are not authorized to view.""";
   }
   lay_content_box_bottom();
   $this->lay_print_nav();
}

function print_theme_preview() {
   var string entry_width;
   var string margin_left;
   var string margin_right;

var string[] link_caption = [
      $*text_editlink,
      $*text_edittagslink,
      $*text_memlink,
      $*text_share,
      $*text_flag,
      $*text_tracklink,
      $*text_read_comments,
      $*text_post_comment,
   ];
   var Link link;
   var string url;
   var string text;

"""
   <div style='background: $*page_bgcolor; color: $*entry_fgcolor; font-family: "$*base_font", $*base_font_fallback; font-size: $*base_font_size; padding: 5px;'>

<div style="margin: 0 0 10px 0;"""; if ($*meta_font_size != "same") { """ font-size: $*meta_font_size;"""; } """ line-height: 120%; text-align: left;">
   <table cellpadding="0" cellspacing="0">
      <tr><td style="vertical-align: top; padding: 0 5px 0 0; font-weight: 700;">Title:</td> <td style="vertical-align: top;"><a style="color: $*entry_fgcolor;" href="#">Lorem ipsum dolor sit amet</a></td></tr>
   </table>
   </div>

Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Nunc tincidunt sollicitudin orci. Vivamus sollicitudin arcu non mi lobortis lacinia. Sed quis orci. Vestibulum in risus sit amet lectus gravida pellentesque. Curabitur faucibus risus eu pede hendrerit eleifend. Nunc vitae odio. Praesent turpis velit, venenatis vitae, accumsan quis, aliquam scelerisque, diam. Nulla fringilla dapibus nulla. Sed in sapien sit amet odio eleifend venenatis. Nunc neque ipsum, convallis id, volutpat eget, bibendum placerat, magna. Integer commodo, nunc eu faucibus tincidunt, est lectus sodales purus, pulvinar pretium purus diam sollicitudin justo. Nulla facilisi. Vivamus eleifend. Fusce sodales dui sit amet dolor.

<div style="margin: 5px 0 0 0;"""; if ($*meta_font_size != "same") { """ font-size: $*meta_font_size;"""; } """ text-align: right;">""";
   foreach var string link ($link_caption) {
      """ $*comment_link_divider <a style="color: $*link_color;" href="#">$link</a>""";
   }
   """
   </div>

</div>
   </div>

</div>
   """;
}

and would like to know if anybody can convert it for DW? I had a little go myself as I used to mess around with LJ layouts years ago and wasn't too bad at it but DW's coding just completely throws me.

Anyway any help would be much appreciated, thanks :)

Threaded | Top-Level Comments Only

From:

momijizukamori

I can give it a go when I have a bit of free time! Two things though - do you have it live on LJ still, just so I can see it? And do you want just the appearance cloned, or the entire underlying HTML/CSS structure? Appearance-only will probably be faster, and will give you access to stuff DW has that LJ doesn't, but you'd have to rewrite existing CSS customizations you've made with new names and whatnot.

jitterylittlething

Hi, thank you for replying.

Would be great if you could have ago, thanks :)

Journal link > http://ditzyfish.livejournal.com

I do like the sound of being able to use DW features as LJ's are a bit more basic aren't they....so yes I think I'll go with the quicker and maybe easier option.

Very kind of you to take the time - you're a gem ;)

Dreamwidth style system discussion

Converting LJ's Gradient Strip Layout

Converting LJ's Gradient Strip Layout

no subject

no subject

Profile

April 2025

Links

Most Popular Tags

Page Summary

Style Credit

Expand Cut Tags